SystemOrganization addCategory: #Seaflash!

WAMultiCounter subclass: #WAFlashMultiCounter
	instanceVariableNames: ''
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Seaflash'!

!WAFlashMultiCounter class methodsFor: 'initialization' stamp: 'lr 8/24/2007 19:06'!
initialize
	self registerAsApplication: 'flash/multicounter'! !

!WAFlashMultiCounter methodsFor: 'rendering' stamp: 'lr 8/30/2007 09:03'!
renderContentOn: html
	html flash: [ :flash | 
		counters do: [ :each | 
			flash paragraph: each ] ]! !

WAObjectTag subclass: #WAFlashTag
	instanceVariableNames: ''
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Seaflash'!

!WAFlashTag methodsFor: 'initialization' stamp: 'lr 8/24/2007 18:53'!
setParent: aBrush canvas: aCanvas
	super setParent: aBrush canvas: aCanvas.
	self type: 'application/x-shockwave-flash'.
	self width: 320; height: 200! !

!WAFlashTag methodsFor: 'public' stamp: 'lr 8/24/2007 19:01'!
with: aBlock
	| movie text  |
	text := SWFText new.
	text
		html: true;
		fontHeight: 30;
		color: (Color gray: 0.1);
		text: (String streamContents: [ :stream |
			| previous document html |
			previous := canvas context document.
			document := SUDocument new.
			document stream: stream.
			canvas context document: document.
			html := canvas species
				context: canvas context
				callbacks: canvas callbacks.
			html render: aBlock; flush.
			canvas context document: previous ]).
	movie := SWFMovie new.
	movie 
		frameWidth: (self attributes at: 'width'); 
		frameHeight: (self attributes at: 'height');
		setBackgroundColor: (Color gray: 0.9);
		placeComponent: text position: 0 @ 0.
	self url: (canvas context 
		urlForDocument: (ByteArray streamContents: [ :stream |
			movie storeOn: stream ])
		mimeType: (self attributes at: 'type')).
	super with: [
		canvas parameter
			name: 'movie';
			value: (self attributes at: 'data').
		canvas parameter
			name: 'loop';
			value: 'false'.
		canvas paragraph: 'Sorry, your browser does not support flash.' ]! !

!WARenderCanvas methodsFor: '*seaflash' stamp: 'lr 8/24/2007 18:02'!
flash
	^ self brush: WAFlashTag new! !

!WARenderCanvas methodsFor: '*seaflash' stamp: 'lr 8/24/2007 18:03'!
flash: aBlock
	^ self flash with: aBlock! !

WACounter subclass: #WAFlashCounter
	instanceVariableNames: ''
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Seaflash'!

!WAFlashCounter class methodsFor: 'initialization' stamp: 'lr 8/24/2007 19:06'!
initialize
	self registerAsApplication: 'flash/counter'! !

!WAFlashCounter methodsFor: 'rendering' stamp: 'lr 8/24/2007 18:34'!
renderContentOn: html
	html flash: [ :flash | super renderContentOn: flash ]! !

WAStore subclass: #WAFlashStore
	instanceVariableNames: ''
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Seaflash'!

!WAFlashStore class methodsFor: 'class initialization' stamp: 'lr 8/24/2007 19:08'!
initialize
	self registerAsApplication: 'flash/store'! !

!WAFlashStore methodsFor: 'rendering' stamp: 'lr 8/24/2007 19:08'!
renderContentOn: html
	html flash
		width: 800;
		height: 600;
		with: [ :flash | super renderContentOn: flash ]! !
WAFlashMultiCounter initialize!
WAFlashCounter initialize!
WAFlashStore initialize!