SystemOrganization addCategory: #'Pier-Site-SCG'!

PRExternalLink subclass: #SCGExternalLink
	instanceVariableNames: ''
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Pier-Site-SCG'!

!SCGExternalLink class methodsFor: 'testing' stamp: 'lr 4/22/2009 11:24'!
isValidReference: aString
	^ (aString beginsWith: '/archive')
		or: [ (aString beginsWith: '/download')
		or: [ (aString beginsWith: '/cgi-bin') ] ]! !

!SCGExternalLink class methodsFor: 'accessing' stamp: 'lr 4/22/2009 11:24'!
priority
	^ 50! !

Object subclass: #SCG
	instanceVariableNames: ''
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Pier-Site-SCG'!

!SCG class methodsFor: 'testing' stamp: 'lr 4/22/2009 11:34'!
isServer
	^ SmalltalkImage current platformName ~= 'Mac OS'! !

ProtoObject subclass: #SCGFileDirectory
	instanceVariableNames: 'name'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Pier-Site-SCG'!

!SCGFileDirectory class methodsFor: 'instance-creation' stamp: 'lr 4/30/2009 21:22'!
on: aString
	^ self basicNew initializeOn: aString! !

!SCGFileDirectory methodsFor: 'system primitives' stamp: 'lr 4/30/2009 21:22'!
doesNotUnderstand: aMessage
	| directory index |
	directory := (FileDirectory default directoryNamed: '../files/..')
		pathParts asOrderedCollection.
	[ (index := directory indexOf: '..') > 0 ] whileTrue: [
		directory removeAt: index.
		index > 1
			ifTrue: [ directory removeAt: index - 1 ] ].
	directory := FileDirectory on: (directory
		reduce: [ :a :b | a , FileDirectory pathNameDelimiter asString , b ]).
	^ aMessage sendTo: directory! !

!SCGFileDirectory methodsFor: 'initialization' stamp: 'lr 4/30/2009 21:14'!
initializeOn: aString
	name := aString! !