SystemOrganization addCategory: #'PetitXml-Core'!
SystemOrganization addCategory: #'PetitXml-Tests'!

PPCompositeParser subclass: #PPXmlGrammar
	instanceVariableNames: 'comment whitespace processing nameStartChar nameChar nameToken nmToken misc document prolog element attributes content characterData attribute'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'PetitXml-Core'!

!PPXmlGrammar methodsFor: 'grammar' stamp: 'lr 1/26/2010 12:46'!
attribute
	"[41] 	Attribute	   ::=   	 Name Eq AttValue"

	^ self parserForAttribute: nameToken value: $" asParser negate star token! !

!PPXmlGrammar methodsFor: 'grammar' stamp: 'lr 1/26/2010 12:46'!
attributes
	"[40]   	STag	   ::=   	'<' Name (S Attribute)* S? '>'	"

	^ ((whitespace , attribute) ==> #second) star! !

!PPXmlGrammar methodsFor: 'grammar-character' stamp: 'lr 1/26/2010 12:42'!
characterData
	"[14]   	CharData	   ::=   	[^<&]* - ([^<&]* ']]>' [^<&]*)"
	
	^ $< asParser negate plus token! !

!PPXmlGrammar methodsFor: 'grammar-misc' stamp: 'lr 1/26/2010 12:48'!
comment
	"[15]   	Comment	   ::=   	'<!!--' ((Char - '-') | ('-' (Char - '-')))* '-->'"

	^ '<!!--' asParser ,  ('-->' asParser not , #any asParser) star , '-->' asParser! !

!PPXmlGrammar methodsFor: 'grammar' stamp: 'lr 1/26/2010 09:29'!
content
	"[43]   	content	   ::=   	 CharData? ((element | Reference | CDSect | PI | Comment) CharData?)*"
				
	^ characterData optional , ((element / processing / comment) , characterData optional) star! !

!PPXmlGrammar methodsFor: 'grammar' stamp: 'lr 1/26/2010 09:22'!
document
	"[1]   	document	   ::=   	 prolog element Misc*"

	^ self parserForDocument: prolog element: element! !

!PPXmlGrammar methodsFor: 'grammar' stamp: 'lr 1/26/2010 11:31'!
element
	"[39]   	element	   ::=   	 EmptyElemTag | STag content ETag"
				
	^ (self parserForTag: nameToken attributes: attributes) / (self parserForTag: nameToken attributes: attributes content: content)! !

!PPXmlGrammar methodsFor: 'grammar-character' stamp: 'lr 1/26/2010 09:08'!
misc
	"[27]   	Misc	   ::=   	 Comment | PI | S"

	^ (whitespace / comment / processing) star! !

!PPXmlGrammar methodsFor: 'token-characters' stamp: 'lr 1/26/2010 09:13'!
nameChar
	"[4a]   	NameChar	   ::=   	 NameStartChar | ""-"" | ""."" | [0-9] | #xB7 | [#x0300-#x036F] | [#x203F-#x2040]"

	^ PPPredicateParser on: [ :char | char = $- or: [ char = $. or: [ char = $: or: [ char = $_ or: [ char isAlphaNumeric ] ] ] ] ] message: 'name expected'! !

!PPXmlGrammar methodsFor: 'token-characters' stamp: 'lr 1/26/2010 09:13'!
nameStartChar
	"[4]   	NameStartChar	   ::=   	"":"" | [A-Z] | ""_"" | [a-z] | [#xC0-#xD6] | [#xD8-#xF6] | [#xF8-#x2FF] | [#x370-#x37D] | [#x37F-#x1FFF] | [#x200C-#x200D] | [#x2070-#x218F] | [#x2C00-#x2FEF] | [#x3001-#xD7FF] | [#xF900-#xFDCF] | [#xFDF0-#xFFFD] | [#x10000-#xEFFFF]"

	^ PPPredicateParser on: [ :char | char = $: or: [ char = $_ or: [ char isLetter ] ] ] message: 'name expected'! !

!PPXmlGrammar methodsFor: 'token' stamp: 'lr 1/26/2010 09:15'!
nameToken
	"[5]   	Name	   ::=   	NameStartChar (NameChar)*"

	^ (nameStartChar , nameChar star) flatten! !

!PPXmlGrammar methodsFor: 'token' stamp: 'lr 1/26/2010 10:41'!
nameTokens
	"[6]   	Names	   ::=   	Name (#x20 Name)*"

	^ (nameToken separatedBy: $ asParser) flatten! !

!PPXmlGrammar methodsFor: 'token' stamp: 'lr 1/26/2010 09:17'!
nmToken
	"[7]   	Nmtoken	   ::=   	(NameChar)+"

	^ nameChar plus flatten! !

!PPXmlGrammar methodsFor: 'token' stamp: 'lr 1/26/2010 09:17'!
nmTokens
	"[8]   	Nmtokens	   ::=   	Nmtoken (#x20 Nmtoken)*"

	^ (nmToken separatedBy: $ asParser) flatten! !

!PPXmlGrammar methodsFor: 'parsers' stamp: 'lr 1/26/2010 11:52'!
parserForAttribute: aNameParser value: aValueParser
	"Answer a parser that can read an XML attribute."

	^ aNameParser asParser token , whitespace optional , $= asParser , whitespace optional , $" asParser , aValueParser asParser , $" asParser
		==> [ :nodes | Array with: nodes first with: nodes sixth ]! !

!PPXmlGrammar methodsFor: 'parsers' stamp: 'lr 1/26/2010 11:53'!
parserForDocument: aPrologParser element: anElementParser
	"Answer a parser that can read an XML document."

	^ aPrologParser asParser , anElementParser asParser , misc
		==> [ :nodes | Array with: nodes first with: nodes second ]! !

!PPXmlGrammar methodsFor: 'parsers' stamp: 'lr 1/26/2010 11:49'!
parserForProcessingInstruction: aTargetParser
	"Answer a parser that can read an XML processing instruction."
	
	^ '<?' asParser , aTargetParser asParser token , (whitespace , ('?>' asParser not , #any asParser) star token) optional , '?>' asParser
		==> [ :nodes | Array with: nodes second with: (nodes third ifNotNil: [ :inner | inner second ]) ]! !

!PPXmlGrammar methodsFor: 'parsers' stamp: 'lr 1/26/2010 09:28'!
parserForTag: aNameParser attributes: anAttributeParser
	"Answer a parser that can read empty XML tags."

	^ self parserForTag: aNameParser attributes: anAttributeParser content: nil! !

!PPXmlGrammar methodsFor: 'parsers' stamp: 'lr 1/26/2010 11:59'!
parserForTag: aNameParser attributes: anAttributeParser content: aContentParser
	"Answer a parser that can read the XML tags."

	^ aContentParser isNil
		ifTrue: [
			$< asParser , aNameParser asParser token , anAttributeParser asParser , whitespace optional , '/>' asParser 
				==> [ :nodes | Array with: nodes second with: nodes third with: nil ] ]
		ifFalse: [
			$< asParser , aNameParser asParser token , anAttributeParser asParser , whitespace optional , $> asParser , aContentParser asParser , 
			[ :stream | stream position ] asParser , '</' asParser , aNameParser asParser token , whitespace optional , $> asParser
				==> [ :nodes |
					nodes second = nodes ninth
						ifTrue: [ Array with: nodes second with: nodes third with: nodes sixth ]
						ifFalse: [ PPFailure reason: 'Expected </' , nodes second value , '> but got </' , nodes ninth value , '>' at: nodes seventh ] ] ]! !

!PPXmlGrammar methodsFor: 'grammar-misc' stamp: 'lr 1/26/2010 10:36'!
processing
	"[16]   	PI	   ::=   	'<?' PITarget (S (Char* - (Char* '?>' Char*)))? '?>'
	[17]   	PITarget	   ::=   	 Name - (('X' | 'x') ('M' | 'm') ('L' | 'l'))"

	^ self parserForProcessingInstruction: #letter asParser plus! !

!PPXmlGrammar methodsFor: 'grammar' stamp: 'lr 1/26/2010 12:44'!
prolog
	"[22]   	prolog	   ::=   	 XMLDecl? Misc* (doctypedecl Misc*)?"
				
	^ (self parserForProcessingInstruction: 'xml') optional , misc
		==> [ :nodes | nodes first ]! !

!PPXmlGrammar methodsFor: 'accessing' stamp: 'lr 1/26/2010 09:25'!
start
	^ document end! !

!PPXmlGrammar methodsFor: 'accessing' stamp: 'lr 1/26/2010 11:45'!
tokenParser
	^ PPXmlTokenParser! !

!PPXmlGrammar methodsFor: 'grammar-misc' stamp: 'lr 1/26/2010 08:46'!
whitespace
	"[3]   	S	   ::=   	(#x20 | #x9 | #xD | #xA)+"

	^ #space asParser plus! !

TestResource subclass: #PPXmlResource
	instanceVariableNames: 'parsers'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'PetitXml-Tests'!

!PPXmlResource methodsFor: 'accessing' stamp: 'lr 1/7/2010 13:55'!
allXsdDefinitions
	^ (self class organization listAtCategoryNamed: #'accessing-xsd')
		collect: [ :each | self perform: each ]! !

!PPXmlResource methodsFor: 'accessing-xsd' stamp: 'lr 1/7/2010 14:06'!
elementFormXsd
	^ '<?xml version="1.0" encoding="UTF-8"?>
<schema
    xmlns="http://www.w3.org/2001/XMLSchema"
    xmlns:xsd="http://www.w3.org/2001/XMLSchema"
    xmlns:tns="http://unqualified-elements.example.com"
    targetNamespace="http://unqualified-elements.example.com">

    <element name="unQualifiedLocals">
        <complexType>
            <sequence>
                <element name="unqualified" type="xsd:string"/>
                <element name="qualified" form="qualified" type="xsd:int"/>
<!!--                <element ref="tns:global"/>-->
            </sequence>
        </complexType>
    </element>

    <element name="global" type="xsd:int"/>

</schema>'! !

!PPXmlResource methodsFor: 'accessing-xsd' stamp: 'lr 1/7/2010 14:06'!
elementReferencesXsd
	^ '<?xml version="1.0" encoding="UTF-8"?>
<schema
        xmlns="http://www.w3.org/2001/XMLSchema"
        xmlns:xsd="http://www.w3.org/2001/XMLSchema"
        xmlns:tns="http://soapinterop.org/types"
        targetNamespace="http://soapinterop.org/types">

    <complexType name="Struct">
        <sequence>
            <element name="varString" type="xsd:string"/>
            <element name="varInt" type="xsd:int"/>
            <element name="varFloat" type="xsd:float"/>
            <element name="varStruct" type="tns:Struct"/>
        </sequence>
    </complexType>

    <element name="attrTest" type="tns:Struct"/>

    <element name="attTests">
        <complexType>
            <sequence>
                <element ref="tns:attrTest" maxOccurs="5"></element>
            </sequence>
        </complexType>
    </element>



</schema>'! !

!PPXmlResource methodsFor: 'accessing-xsd' stamp: 'lr 1/7/2010 14:06'!
externalAttributesXsd
	^ '<?xml version="1.0" encoding="UTF-8"?>
<schema
    xmlns="http://www.w3.org/2001/XMLSchema"
    xmlns:xsd="http://www.w3.org/2001/XMLSchema"
    xmlns:tns="http://unqualified-elements.example.com"
    xmlns:test="http://test-namespace"
    targetNamespace="http://unqualified-elements.example.com"
    test:level="1">

    <element name="AnyAttContainer" test:level="2">
        <complexType>
            <sequence>
                <element name="chileValue" type="xsd:string"/>
            </sequence>
            <anyAttribute namespace="##other" processContents="lax"></anyAttribute>
        </complexType>
    </element>

    <element name="global" type="xsd:int"/>

</schema>'! !

!PPXmlResource methodsFor: 'accessing-xsd' stamp: 'lr 1/7/2010 14:06'!
forwardRefXsd
	^ '<?xml version="1.0" encoding="UTF-8"?>
<!!--
 * Copyright 2004,2005 The Apache Software Foundation.
 * Copyright 2006 International Business Machines Corp.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 *
-->

<schema xmlns="http://www.w3.org/2001/XMLSchema"
        xmlns:xsd="http://www.w3.org/2001/XMLSchema"
        xmlns:tns="http://soapinterop.org/types"
        targetNamespace="http://soapinterop.org/types">

    <simpleType name="zipCode">
      <restriction base="string">
        <length value="5"/>
        <pattern value="\d{5}"/>
      </restriction>
    </simpleType>
    <element name="myZipCode" type="tns:zipCode"/>

    <simpleType name="age">
      <restriction base="decimal">
        <totalDigits value="3"/>
      </restriction>
    </simpleType>
    <element name="myAge" type="tns:age"/>

    <simpleType name="distance">
      <restriction base="integer">
        <maxInclusive value="100" fixed="true"/>
        <minInclusive value="0"/>
      </restriction>
    </simpleType>
    <element name="myDistance" type="tns:distance"/>

    <simpleType name="weight">
      <restriction base="integer">
        <maxExclusive value="200"/>
        <minExclusive value="1"/>
      </restriction>
    </simpleType>
    <element name="myWeight" type="tns:weight"/>

    <simpleType name="creditCardNumber">
      <restriction base="integer">
        <pattern value="\d{15}"/>
      </restriction>
    </simpleType>
    <element name="myCreditCardNumber" type="tns:creditCardNumber"/>

    <simpleType name="noWhiteSpace">
      <restriction base="normalizedString">
        <whiteSpace value="collapse"/>
      </restriction>
    </simpleType>
    <element name="myWhiteSpace" type="tns:noWhiteSpace"/>

    <simpleType name="petWeight">
      <restriction base="tns:weight">
        <maxExclusive value="50"/>
        <minExclusive value="5"/>
      </restriction>
    </simpleType>

    <simpleType name="fixedDistance">
      <restriction base="tns:distance">
        <minInclusive value="1"/>
      </restriction>
    </simpleType>

    <simpleType name="height">
      <restriction base="decimal">
        <totalDigits value="3"/>
        <fractionDigits value="2"/>
      </restriction>
    </simpleType>
    <element name="myHeight" type="tns:height"/>

    <simpleType name="yardLength">
      <restriction base="nonNegativeInteger">
        <minLength value="45"/>
        <maxLength value="205"/>
      </restriction>
    </simpleType>
    <element name="myYardLength" type="tns:yardLength"/>

    <simpleType name="layoutComponentType">
      <restriction base="string">
        <enumeration value="Field"/>
        <enumeration value="Separator"/>
      </restriction>
    </simpleType>
    <element name="layoutComponent" type="tns:layoutComponentType"/>

</schema>'! !

!PPXmlResource methodsFor: 'accessing-xsd' stamp: 'lr 1/7/2010 13:52'!
getBalanceXsd
	^ '<?xml version="1.0" encoding="UTF-8"?>
<xsd:schema xmlns:xsd="http://www.w3.org/2001/XMLSchema">
        <xsd:complexType name="cinfoct">
                <xsd:sequence>
                        <xsd:element name="customerSurname" type="xsd:string" />
                        <xsd:element name="customerForname" type="xsd:string" />
                        <xsd:element name="branchCode">
                                <xsd:simpleType>
                                        <xsd:restriction base="xsd:string">
                                                <xsd:pattern
                                                        value="[0-9]{2}[\-][0-9]{2}[\-][0-9]{2}" />
                                        </xsd:restriction>
                                </xsd:simpleType>
                        </xsd:element>
                </xsd:sequence>
        </xsd:complexType>
        <xsd:element name="custInfo" type="cinfoct" />
        <xsd:complexType name="accinfct">
                <xsd:sequence maxOccurs="unbounded" minOccurs="0">
                        <xsd:element name="accName">
                                <xsd:simpleType>
                                        <xsd:restriction base="xsd:string">
                                                <xsd:enumeration value="Cheque" />
                                                <xsd:enumeration value="Credit" />
                                                <xsd:enumeration value="Savings" />
                                                <xsd:enumeration value="Loan" />
                                        </xsd:restriction>
                                </xsd:simpleType>
                        </xsd:element>
                        <xsd:element name="accNumber">
                                <xsd:simpleType>
                                        <xsd:restriction base="xsd:string">
                                                <xsd:pattern value="[0-9]{12}" />
                                        </xsd:restriction>
                                </xsd:simpleType>
                        </xsd:element>
                        <xsd:element name="accBalance">
                                <xsd:simpleType>
                                        <xsd:restriction base="xsd:decimal">
                                                <xsd:fractionDigits value="2" />
                                        </xsd:restriction>
                                </xsd:simpleType>
                        </xsd:element>
                </xsd:sequence>
        </xsd:complexType>
        <xsd:element name="accInfo" type="accinfct" />
</xsd:schema>'! !

!PPXmlResource methodsFor: 'accessing-xsd' stamp: 'lr 1/7/2010 14:06'!
groupXsd
	^ '<?xml version="1.0" encoding="UTF-8"?>
<schema xmlns="http://www.w3.org/2001/XMLSchema"
        xmlns:xsd="http://www.w3.org/2001/XMLSchema"
        xmlns:tns="http://soapinterop.org/types"
        targetNamespace="http://soapinterop.org/types">

  <group name="priceGroup">
    <annotation>
      <documentation xml:lang="en">
                A price is any one of the following:
                    * Full Price (with amount)
                    * Sale Price (with amount and authorization)
                    * Clearance Price (with amount and authorization)
                    * Free (with authorization)
      </documentation>
    </annotation>
    <choice id="pg.choice">
      <element name="fullPrice" type="decimal"/>
      <element name="salePrice" type="decimal"/>
      <element name="clearancePrice" type="decimal"/>
      <element name="freePrice" type="decimal"/>
    </choice>
  </group>

  <element name="price">
    <complexType>
      <group ref="tns:priceGroup" />
    </complexType>
  </element>

</schema>'! !

!PPXmlResource methodsFor: 'accessing-xsd' stamp: 'lr 1/7/2010 14:06'!
importAuxXsd
	^ '<?xml version="1.0" encoding="UTF-8"?>
<schema targetNamespace="http://soapinterop.org/xsd2"
        xmlns="http://www.w3.org/2001/XMLSchema"
        xmlns:wsdl="http://schemas.xmlsoap.org/wsdl/"
        xmlns:xsd="http://www.w3.org/2001/XMLSchema"
        xmlns:xsd1="http://soapinterop.org/xsd2"
        elementFormDefault="qualified">
    <complexType name="SOAPStruct">
        <all>
            <element name="varFloat" type="xsd:float"/>
            <element name="varInt" type="xsd:int"/>
            <element name="varString" type="xsd:string"/>
        </all>
    </complexType>
</schema>'! !

!PPXmlResource methodsFor: 'accessing-xsd' stamp: 'lr 1/7/2010 14:06'!
importBaseXsd
	^ '<?xml version="1.0" encoding="UTF-8"?>
<schema targetNamespace="http://soapinterop.org/xsd"
        xmlns="http://www.w3.org/2001/XMLSchema"
        xmlns:wsdl="http://schemas.xmlsoap.org/wsdl/"
        xmlns:xsd="http://www.w3.org/2001/XMLSchema"
        xmlns:xsd1="http://soapinterop.org/xsd"
        xmlns:xsd2="http://soapinterop.org/xsd2"
        elementFormDefault="qualified">
    <import namespace="http://soapinterop.org/xsd2" schemaLocation="importAux.xsd"></import>
    <element name="echoStructParam" type="xsd2:SOAPStruct"/>
</schema>'! !

!PPXmlResource methodsFor: 'accessing-xsd' stamp: 'lr 1/7/2010 13:50'!
includeWithNamespaceXsd
	^ '<?xml version="1.0" encoding="UTF-8"?>
<xs:schema
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:tns="http://tns.demo.org"
    targetNamespace="http://tns.demo.org"
    attributeFormDefault="unqualified"
    elementFormDefault="qualified">
  <xs:include schemaLocation="src/test/test-resources/includedWithoutNamespace.xsd"/>

  <xs:element name="foo" type="tns:XdwsGroupId"/>
</xs:schema>'! !

!PPXmlResource methodsFor: 'accessing-xsd' stamp: 'lr 1/7/2010 13:50'!
includeWithoutNamespaceXsd
	^ '<?xml version="1.0" encoding="UTF-8"?>
<xs:schema
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    attributeFormDefault="unqualified"
    elementFormDefault="qualified">
  <xs:simpleType name="XdwsPrincipalId">
    <xs:restriction base="xs:string"/>
  </xs:simpleType>

  <xs:simpleType name="XdwsGroupId">
    <xs:restriction base="XdwsPrincipalId"/>
  </xs:simpleType>
</xs:schema>'! !

!PPXmlResource methodsFor: 'accessing-xsd' stamp: 'lr 1/7/2010 14:06'!
listXsd
	^ '<?xml version="1.0" encoding="UTF-8"?>
<schema xmlns="http://www.w3.org/2001/XMLSchema"
        xmlns:xsd="http://www.w3.org/2001/XMLSchema"
        xmlns:tns="http://soapinterop.org/types"
        targetNamespace="http://soapinterop.org/types">

  <element name="workDays">
    <simpleType>
      <restriction base="tns:daysInWeek">
        <length value="5"/>
      </restriction>
    </simpleType>
  </element>

  <simpleType name="daysInWeek">
    <list itemType="xsd:integer"/>
  </simpleType>

</schema>'! !

!PPXmlResource methodsFor: 'accessing-xsd' stamp: 'lr 1/7/2010 14:06'!
mixedContentXsd
	^ '<?xml version="1.0" encoding="UTF-8"?>
<schema targetNamespace="http://soapinterop.org/xsd"
        xmlns="http://www.w3.org/2001/XMLSchema"
        xmlns:wsdl="http://schemas.xmlsoap.org/wsdl/"
        xmlns:xsd="http://www.w3.org/2001/XMLSchema"
        xmlns:xsd1="http://soapinterop.org/xsd"
        xmlns:xsd2="http://soapinterop.org/xsd2"
        elementFormDefault="qualified">
     <element name="complexElt">
         <complexType mixed="true">
             <sequence>
                  <element name="name" type="string"/>
                  <element name="age" type="int"/>
             </sequence>
         </complexType>
     </element>
</schema>'! !

!PPXmlResource methodsFor: 'accessing-xsd' stamp: 'lr 1/7/2010 14:06'!
notationXsd
	^ '<?xml version="1.0" encoding="UTF-8"?>
<schema xmlns="http://www.w3.org/2001/XMLSchema"
        xmlns:xsd="http://www.w3.org/2001/XMLSchema"
        xmlns:tns="http://soapinterop.org/types"
        targetNamespace="http://soapinterop.org/types">

  <notation name="teamLogo"
            system="com/team/graphics/teamLogo"
            public="http://www.team.com/graphics/teamLogo"
            id="notation.teamLogo">
    <annotation>
      <documentation xml:lang="en">Location of the corporate logo.</documentation>
    </annotation>
  </notation>

  <notation name="teamMascot"
            system="com/team/graphics/teamMascot"
            public="http://www.team.com/graphics/teamMascot"
            id="notation.teamMascot">
    <annotation>
      <documentation xml:lang="en">Location of the corporate mascot.</documentation>
    </annotation>
  </notation>

  <element name="demoNotation">
    <simpleType>
      <restriction base="NOTATION">
        <enumeration value="tns:teamLogo"/>
        <enumeration value="tns:teamMascot"/>
      </restriction>
    </simpleType>
  </element>

</schema>'! !

!PPXmlResource methodsFor: 'accessing' stamp: 'lr 1/26/2010 10:42'!
parserAt: aClass 
	^ aClass new "parsers 
		at: aClass name
		ifAbsentPut: [ aClass new ]"! !

!PPXmlResource methodsFor: 'accessing-xsd' stamp: 'lr 1/7/2010 14:06'!
restrictionXsd
	^ '<?xml version="1.0" encoding="UTF-8"?>
<schema xmlns="http://www.w3.org/2001/XMLSchema"
        xmlns:xsd="http://www.w3.org/2001/XMLSchema"
        xmlns:tns="http://soapinterop.org/types"
        targetNamespace="http://soapinterop.org/types"
        attributeFormDefault="qualified">

  <simpleType name="drinksize">
    <restriction base="string">
      <enumeration value="small"/>
      <enumeration value="medium"/>
      <enumeration value="large"/>
    </restriction>
  </simpleType>

  <complexType name="dietdrinksize">
    <simpleContent>
      <restriction base="tns:drinksize">
        <enumeration value="small"/>
        <enumeration value="medium"/>
        <attribute name="units" type="string" use="required"/>
        <attribute name="id" type="integer" use="required" default="001"/>
      </restriction>
    </simpleContent>
  </complexType>

</schema>'! !

!PPXmlResource methodsFor: 'running' stamp: 'lr 1/7/2010 13:39'!
setUp
	super setUp.
	parsers := Dictionary new! !

!PPXmlResource methodsFor: 'accessing-xsd' stamp: 'lr 1/7/2010 14:06'!
simpleContentExtensionXsd
	^ '<?xml version="1.0" encoding="UTF-8"?>
<schema xmlns="http://www.w3.org/2001/XMLSchema"
        xmlns:xsd="http://www.w3.org/2001/XMLSchema"
        xmlns:tns="http://soapinterop.org/types"
        targetNamespace="http://soapinterop.org/types">

  <element name="ID" type="string"/>

  <element name="Name" substitutionGroup="tns:ID" type="string"/>

  <element name="IDBlock" type="string" block="substitution"/>

  <element name="TestSubstitutionGroup">
    <complexType>
      <sequence>
        <element ref="tns:ID"/>
      </sequence>
    </complexType>
  </element>

</schema>'! !

!PPXmlResource methodsFor: 'accessing-xsd' stamp: 'lr 1/7/2010 14:07'!
subgroupXsd
	^ '<?xml version="1.0" encoding="UTF-8"?>
<schema xmlns="http://www.w3.org/2001/XMLSchema"
        xmlns:xsd="http://www.w3.org/2001/XMLSchema"
        xmlns:tns="http://soapinterop.org/types"
        targetNamespace="http://soapinterop.org/types">

  <element name="ID" type="string"/>

  <element name="Name" substitutionGroup="tns:ID" type="string"/>

  <element name="IDBlock" type="string" block="substitution"/>

  <element name="TestSubstitutionGroup">
    <complexType>
      <sequence>
        <element ref="tns:ID"/>
      </sequence>
    </complexType>
  </element>

</schema>'! !

!PPXmlResource methodsFor: 'accessing-xsd' stamp: 'lr 1/7/2010 14:07'!
unionXsd
	^ '<?xml version="1.0" encoding="UTF-8"?>
<schema xmlns="http://www.w3.org/2001/XMLSchema"
        xmlns:xsd="http://www.w3.org/2001/XMLSchema"
        xmlns:tns="http://soapinterop.org/types"
        targetNamespace="http://soapinterop.org/types">

  <element name="unionTest">
    <simpleType>
      <union memberTypes="float decimal"/>
    </simpleType>
  </element>

</schema>'! !

!PPXmlResource methodsFor: 'accessing-xsd' stamp: 'lr 1/7/2010 14:07'!
unqualifiedTypesXsd
	^ '<?xml version="1.0" encoding="UTF-8"?>
<schema targetNamespace="http://soapinterop.org/xsd"
        xmlns="http://www.w3.org/2001/XMLSchema"
        xmlns:wsdl="http://schemas.xmlsoap.org/wsdl/"
        xmlns:xsd="http://www.w3.org/2001/XMLSchema"
        xmlns:xsd1="http://soapinterop.org/xsd"
        xmlns:xsd2="http://soapinterop.org/xsd2"
        elementFormDefault="qualified">
     <element name="complexElt">
         <complexType>
             <sequence>
                  <element name="name" type="string"/>
                  <element name="age" type="int"/>
             </sequence>
         </complexType>
     </element>
</schema>'! !

PPFlattenParser subclass: #PPXmlTokenParser
	instanceVariableNames: ''
	classVariableNames: ''
	poolDictionaries: ''
	category: 'PetitXml-Core'!

!PPXmlTokenParser methodsFor: 'hooks' stamp: 'lr 1/26/2010 11:44'!
create: aCollection start: aStartInteger stop: aStopInteger
	^ PPToken on: aCollection start: aStartInteger stop: aStopInteger! !

TestCase subclass: #PPXmlTest
	instanceVariableNames: 'result'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'PetitXml-Tests'!

PPXmlTest subclass: #PPXmlGrammarTest
	instanceVariableNames: ''
	classVariableNames: ''
	poolDictionaries: ''
	category: 'PetitXml-Tests'!

!PPXmlGrammarTest methodsFor: 'as yet unclassified' stamp: 'TestRunner 1/7/2010 14:03'!
parserClass
	^ PPXmlGrammar! !

!PPXmlGrammarTest methodsFor: 'as yet unclassified' stamp: 'lr 1/26/2010 10:48'!
testParseAll
	self resource allXsdDefinitions 
		do: [ :each | self parse: each ]! !

!PPXmlGrammarTest methodsFor: 'as yet unclassified' stamp: 'lr 1/26/2010 10:55'!
testParseComment
	self parse: '<?xml version="1.0" encoding="UTF-8"?><schema><!!-- comment --></schema>' ! !

!PPXmlGrammarTest methodsFor: 'as yet unclassified' stamp: 'lr 1/26/2010 10:56'!
testParseCommentWithXml
	self parse: '<?xml version="1.0" encoding="UTF-8"?><schema><!!-- <foo></foo> --></schema>' ! !

!PPXmlGrammarTest methodsFor: 'as yet unclassified' stamp: 'lr 1/26/2010 12:40'!
testParseComplicated
	self parse: '<?xml foo?>
<foo>
	<bar a="fasdfasdf">
		<zork/>
		<zonk/>
	</bar>
	<!!-- with comment -->
</foo>' ! !

!PPXmlGrammarTest methodsFor: 'as yet unclassified' stamp: 'lr 1/26/2010 10:56'!
testParseEmptyElement
	self parse: '<?xml version="1.0" encoding="UTF-8"?><schema/>' ! !

!PPXmlGrammarTest methodsFor: 'as yet unclassified' stamp: 'lr 1/26/2010 10:48'!
testParseSimple
	self parse: '<?xml version="1.0" encoding="UTF-8"?><schema></schema>' ! !

!PPXmlGrammarTest methodsFor: 'as yet unclassified' stamp: 'lr 1/26/2010 11:00'!
testParseSimpleAttribute
	self parse: '<?xml version="1.0" encoding="UTF-8"?><schema foo="bar"></schema>' ! !

!PPXmlGrammarTest methodsFor: 'as yet unclassified' stamp: 'lr 1/26/2010 10:57'!
testParseWithWhitsepaceAfterProlog
	self parse: '<?xml version="1.0" encoding="UTF-8"?>
	<schema></schema>' ! !

!PPXmlTest class methodsFor: 'testing' stamp: 'lr 1/7/2010 14:01'!
isAbstract
	^ self name ~= #PPXmlGrammarTest! !

!PPXmlTest class methodsFor: 'accessing' stamp: 'lr 1/7/2010 13:40'!
packageNamesUnderTest
	^ #('PetitXml')! !

!PPXmlTest class methodsFor: 'accessing' stamp: 'lr 1/7/2010 13:41'!
resources
	^ Array with: PPXmlResource! !

!PPXmlTest methodsFor: 'parsing' stamp: 'TestRunner 1/7/2010 14:42'!
parse: aString
	self parse: aString rule: #start! !

!PPXmlTest methodsFor: 'parsing' stamp: 'lr 1/7/2010 13:41'!
parse: aString rule: aSymbol 
	| production |
	production := self parser.
	aSymbol = #start 
		ifFalse: [ production := production instVarNamed: aSymbol ].
	result := production end
		parse: aString asParserStream.
	self 
		deny: result isFailure
		description: 'Unable to parse ' , aString printString! !

!PPXmlTest methodsFor: 'accessing' stamp: 'lr 1/7/2010 13:56'!
parser
	^ self resource parserAt: self parserClass! !

!PPXmlTest methodsFor: 'accessing' stamp: 'lr 1/7/2010 13:41'!
parserClass
	self subclassResponsibility! !

!PPXmlTest methodsFor: 'accessing' stamp: 'TestRunner 1/7/2010 14:03'!
resource
	^ PPXmlResource current! !