SystemOrganization addCategory: #Announcements!

Set subclass: #AnnouncementSet
	instanceVariableNames: ''
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Announcements'!

!AnnouncementSet methodsFor: 'adding' stamp: 'lr 6/13/2006 08:13'!
, anAnnouncementClass
	self add: anAnnouncementClass! !

!AnnouncementSet methodsFor: 'testing' stamp: 'lr 6/13/2006 08:13'!
handles: anAnnouncement
	^ self anySatisfy: [ :each | each handles: anAnnouncement ]! !

Object subclass: #Announcement
	instanceVariableNames: ''
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Announcements'!

!Announcement class methodsFor: 'public' stamp: 'lr 9/20/2006 08:18'!
, anAnnouncementClass
	^ AnnouncementSet with: self with: anAnnouncementClass! !

!Announcement class methodsFor: 'public' stamp: 'lr 9/20/2006 08:18'!
andSubclasses
	^ AnnouncementSet withAll: self withAllSubclasses! !

!Announcement class methodsFor: 'testing' stamp: 'lr 7/5/2006 13:14'!
handles: anAnnouncement
	^ anAnnouncement isKindOf: self! !

!Announcement methodsFor: 'morphic' stamp: 'lr 9/3/2006 16:17'!
open
	self inspect! !

Object subclass: #AnnouncementSpy
	instanceVariableNames: 'announcer announcements index'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Announcements'!

!AnnouncementSpy class methodsFor: 'instance-creation' stamp: 'lr 6/14/2006 17:05'!
on: anAnnouncer
	^ self new
		announcer: anAnnouncer;
		yourself! !

!AnnouncementSpy class methodsFor: 'instance-creation' stamp: 'lr 6/14/2006 17:05'!
openOn: anAnnouncer
	ToolBuilder open: (self on: anAnnouncer)! !

!AnnouncementSpy methodsFor: 'private' stamp: 'lr 9/3/2006 14:09'!
announce: anAnnouncement
	self announcements add: anAnnouncement.
	self index: self announcements size.
	self changed: #announcements! !

!AnnouncementSpy methodsFor: 'accessing' stamp: 'lr 6/14/2006 17:02'!
announcements
	^ announcements! !

!AnnouncementSpy methodsFor: 'accessing' stamp: 'lr 9/3/2006 14:08'!
announcements: aCollection
	announcements := aCollection.
	self changed: #announcements! !

!AnnouncementSpy methodsFor: 'accessing' stamp: 'lr 6/14/2006 17:04'!
announcer
	^ announcer! !

!AnnouncementSpy methodsFor: 'accessing' stamp: 'lr 9/20/2006 08:18'!
announcer: anAnnouncer
	announcer := anAnnouncer.
	announcer subscribe: Announcement send: #announce: to: self! !

!AnnouncementSpy methodsFor: 'building' stamp: 'lr 9/3/2006 16:21'!
buildMenu: aMenuMorph
	^ aMenuMorph
		defaultTarget: self;
		add: 'open' action: #open;
		add: 'clear' action: #clear;
		yourself! !

!AnnouncementSpy methodsFor: 'building' stamp: 'lr 9/3/2006 14:08'!
buildWith: aBuilder
	^ aBuilder build: (aBuilder pluggableWindowSpec new
		model: self; label: self label; extent: self extent;
		children: (OrderedCollection new
			add: (aBuilder pluggableListSpec new
				model: self;
				list: #announcements;
				menu: #buildMenu:;
				getIndex: #index;
				setIndex: #index:;
				frame: (0 @ 0 corner: 1 @ 1);
				yourself);
			yourself);
		yourself)! !

!AnnouncementSpy methodsFor: 'private' stamp: 'lr 6/14/2006 17:19'!
changed: aSymbol
	WorldState addDeferredUIMessage: [ super changed: aSymbol ]! !

!AnnouncementSpy methodsFor: 'actions' stamp: 'lr 9/3/2006 16:21'!
clear
	self announcements: OrderedCollection new! !

!AnnouncementSpy methodsFor: 'accessing-dynamic' stamp: 'lr 9/3/2006 14:08'!
extent
	^ 250 @ 400! !

!AnnouncementSpy methodsFor: 'accessing' stamp: 'lr 6/14/2006 17:02'!
index
	^ index ! !

!AnnouncementSpy methodsFor: 'accessing' stamp: 'lr 6/14/2006 17:20'!
index: anInteger
	index := anInteger.
	self changed: #index! !

!AnnouncementSpy methodsFor: 'initialization' stamp: 'lr 6/14/2006 17:03'!
initialize
	super initialize.
	self announcements: OrderedCollection new.
	self index: 0! !

!AnnouncementSpy methodsFor: 'accessing-dynamic' stamp: 'lr 6/14/2006 17:03'!
label
	^ self announcer printString! !

!AnnouncementSpy methodsFor: 'actions' stamp: 'lr 9/3/2006 16:21'!
open
	(self announcements at: self index) 
		open! !

!AnnouncementSpy methodsFor: 'private' stamp: 'lr 6/14/2006 17:29'!
perform: selector orSendTo: otherTarget
	^ (self respondsTo: selector)
		ifTrue: [ self perform: selector ]
		ifFalse: [ super perform: selector orSendTo: otherTarget ]! !

Object subclass: #Announcer
	instanceVariableNames: 'subscriptions'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Announcements'!

!Announcer methodsFor: 'announce' stamp: 'lr 7/5/2006 13:14'!
announce: anAnnouncement
	subscriptions keysAndValuesDo: [ :class :action |
		(class handles: anAnnouncement) 
			ifTrue: [ action valueWithArguments: (Array with: anAnnouncement) ] ].
	^ anAnnouncement! !

!Announcer methodsFor: 'initialization' stamp: 'lr 7/5/2006 13:14'!
initialize
	super initialize.
	subscriptions := IdentityDictionary new! !

!Announcer methodsFor: 'morphic' stamp: 'lr 9/20/2006 08:18'!
open
	AnnouncementSpy openOn: self! !

!Announcer methodsFor: 'subscription' stamp: 'lr 6/13/2006 08:02'!
subscribe: aClass do: aValuable 
	| actions |
	actions := subscriptions at: aClass ifAbsent: [ ActionSequence new ].
	subscriptions at: aClass put: (actions copyWith: aValuable)! !

!Announcer methodsFor: 'subscription' stamp: 'lr 6/13/2006 08:02'!
subscribe: aClass send: aSelector to: anObject
	self subscribe: aClass do: (MessageSend receiver: anObject selector: aSelector)! !