SystemOrganization addCategory: #'OB-Wrapper'!

ORCmdEnvironment subclass: #ORCmdCoverage
	instanceVariableNames: ''
	classVariableNames: ''
	poolDictionaries: ''
	category: 'OB-Wrapper'!

!ORCmdCoverage methodsFor: 'accessing' stamp: 'lr 4/26/2010 16:50'!
environment
	| wrappers environment |
	wrappers := OrderedCollection new.
	super environment classesAndSelectorsDo: [ :class :selector |
		wrappers addLast: (TestCoverage 
			on: (MethodReference class: class selector: selector)) ].
	wrappers do: [ :each | each install ].
	[ OBInformRequest message: 'Coverage analysis of ' , wrappers size asString , ' methods...' ]
		ensure: [ wrappers do: [ :each | each uninstall ] ].
	environment := SelectorEnvironment onEnvironment: super environment.
	environment label: 'Coverage of ' , super environment label.
	wrappers do: [ :each | 
		each hasRun
			ifTrue: [ environment addClass: each reference actualClass selector: each reference selector ] ].
	^ environment
	
! !

!ORCmdCoverage methodsFor: 'accessing' stamp: 'lr 4/26/2010 16:48'!
group
	^ #abstract! !

!ORCmdCoverage methodsFor: 'testing' stamp: 'lr 4/26/2010 16:39'!
isActive
	^ super isActive and: [ super environment isSystem not ]! !

!ORCmdCoverage methodsFor: 'testing' stamp: 'lr 4/26/2010 16:31'!
label
	^ 'coverage...'! !