SystemOrganization addCategory: #'Helvetia-Loader'!

Object subclass: #CHHelvetiaLoader
	instanceVariableNames: ''
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Helvetia-Loader'!

!CHHelvetiaLoader class methodsFor: 'installing-settings (4000)' stamp: 'lr 2/14/2010 11:04'!
defineDesign
	<install: 'Updating System Design' priority: 4000>

	UIThemeStandardSqueak beCurrent.
	World submorphs do: [ :each |
		(each isKindOf: SketchMorph)
			ifTrue: [ each delete ] ]! !

!CHHelvetiaLoader class methodsFor: 'installing-settings (4000)' stamp: 'lr 2/14/2010 11:04'!
defineFonts
	<install: 'Setting System Fonts' priority: 4100>

	StrikeFont installDejaVu.
	Preferences setDefaultFonts: #(
		(setBalloonHelpFontTo: 'BitmapDejaVu' 9)
		(setButtonFontTo: 'BitmapDejaVu' 9)
		(setCodeFontTo: 'BitmapDejaVu' 9)
		(setHaloLabelFontTo: 'BitmapDejaVu' 9)
		(setListFontTo: 'BitmapDejaVu' 9)
		(setMenuFontTo: 'BitmapDejaVu' 9)
		(setSystemFontTo: 'BitmapDejaVu' 9)
		(setWindowTitleFontTo: 'BitmapDejaVuBold' 12))! !

!CHHelvetiaLoader class methodsFor: 'installing-settings (4000)' stamp: 'lr 2/14/2010 11:04'!
definePreferences
	<install: 'Setting System Preferences' priority: 4200>
	
	Preferences enable: #scrollBarsNarrow.
	Preferences enable: #menuColorFromWorld.
	Preferences disable: #scrollBarsWithoutMenuButton.
	Preferences disable: #useNewDiffToolsForMC.
	Preferences disable: #duplicateAllControlAndAltKeys.
	Preferences disable: #fadedBackgroundWindows.
	Preferences disable: #windowAnimation.
	Preferences disable: #noWindowAnimationForClosing! !

!CHHelvetiaLoader class methodsFor: 'initialization' stamp: 'lr 1/11/2010 10:53'!
initialize
	self specification
		do: [ :pragma |
			pragma arguments first isString
				ifTrue: [ ProgressNotification signal: '' extra: pragma arguments first ].
			self perform: pragma selector ]
		displayingProgress: 'Loading Helvetia'! !

!CHHelvetiaLoader class methodsFor: 'installing-tools (2000)' stamp: 'lr 2/14/2010 11:01'!
loadDevelopmentTools
	<install: 'Loading Development Tools' priority: 2200>
	
	Gofer new
		renggli: 'unsorted';
		package: 'Shout';
		package: 'RoelTyper';
		package: 'ECompletion';
		package: 'ECompletionOmniBrowser';
		load! !

!CHHelvetiaLoader class methodsFor: 'installing-helvetia (3000)' stamp: 'lr 2/18/2010 20:23'!
loadHelvetia
	<install: 'Loading Helvetia System' priority: 3000>
	
	Gofer new
		renggli: 'helvetia';
		package: 'QuasiQuote';
		package: 'Helvetia-Core';
		load.
	CHCompiler enable! !

!CHHelvetiaLoader class methodsFor: 'installing-helvetia (3000)' stamp: 'lr 2/18/2010 20:24'!
loadHelvetiaExamples
	<install: 'Loading Helvetia Examples' priority: 3100>
	
	Gofer new
		renggli: 'helvetia';
		package: 'Cutie-Helvetia';
		load! !

!CHHelvetiaLoader class methodsFor: 'installing-tools (2000)' stamp: 'lr 2/14/2010 10:59'!
loadOmniBrowser
	<install: 'Loading OmniBrowser' priority: 2100>
	
	Gofer new
		renggli: 'omnibrowser';
		package: 'OmniBrowser';
		package: 'OB-Standard';
		package: 'OB-Morphic';
		package: 'OB-Shout';
		package: 'OB-Refactory';
		package: 'OB-Regex';
		package: 'OB-SUnitIntegration';
		load.
	SystemBrowser default: (Smalltalk at: #OBSystemBrowserAdaptor)! !

!CHHelvetiaLoader class methodsFor: 'installing-tools (2000)' stamp: 'lr 2/14/2010 11:01'!
loadPetitParser
	<install: 'Loading PetitParser' priority: 2300>
	
	Gofer new
		renggli: 'petit';
		package: 'PetitParser';
		package: 'PetitAnalyzer';
		package: 'PetitSmalltalk';
		load! !

!CHHelvetiaLoader class methodsFor: 'installing-tools (2000)' stamp: 'lr 2/14/2010 10:59'!
loadRefactoringEngine
	<install: 'Loading Refactoring Engine' priority: 2000>
	
	Gofer new
		squeaksource: 'rb';
		package: 'AST-Core';
		package: 'AST-Compiler';
		package: 'Refactoring-Core';
		package: 'Refactoring-Spelling';
		load! !

!CHHelvetiaLoader class methodsFor: 'initialization' stamp: 'lr 1/11/2010 10:46'!
specification
	^ Pragma allNamed: #install:priority: in: self class sortedByArgument: 2! !

!CHHelvetiaLoader class methodsFor: 'installing-validation (1000)' stamp: 'lr 2/14/2010 10:59'!
validateGofer
	<install: 'Validating Gofer' priority: 1010>
	
	(Smalltalk hasClassNamed: 'Gofer')
		ifFalse: [ self error: 'Helvetia requires a recent version of Gofer.' ].
	Gofer upgrade; upgrade! !

!CHHelvetiaLoader class methodsFor: 'installing-validation (1000)' stamp: 'lr 2/18/2010 20:36'!
validatePlatform
	<install: 'Validate Platform' priority: 1000>

	(SystemVersion current version beginsWith: 'PharoCore1.0')
		ifFalse: [ self notify: 'Helvetia might not work with this image: ' , SystemVersion current version , '. Please consider using a PharoCore 1.0 image.' ].
	(SystemVersion current highestUpdate >=  10502)
		ifFalse: [ self notify: 'Helvetia might not work with this image: ' , SystemVersion current version , '. Please consider using a PharoCore 1.0 image.' ]! !
CHHelvetiaLoader initialize!